10 ARRAY
100 INPUT #1;"FROM ? ";N$
110 PRINT #1;"TO FLP2_INSTALL_DBS"
120 :
130 OPEN_IN #4;N$
140 OPEN_DATA #3;FLP2_INSTALL_DBS
150 INPUT #4;A$
160 IF A$<>"ins1" THEN STOP
165 INPUT #4;A$
167 INPUT #4;Number
170 :
180 FOR LP=0 TO Number
190  INPUT #4;A$
194  IF LEN(A$)>FLLEN(#3;2) THEN A$=A$(1 TO FLLEN(#3;2))
197  SET #3;2,A$
200  INPUT #4;A$
204  IF LEN(A$)>FLLEN(#3;4) THEN A$=A$(1 TO FLLEN(#3;4))
207  SET #3;4,A$
210  FOR CST=10 TO 30
220   INPUT #4;A$: SET #3;CST;CONV$(A$)
230  END FOR CST
240  INPUT #4;A%: SET #3;6,PARITY$(A%)
250  INPUT #4;A%: SET #3;8,A%
260  INPUT #4;A%: SET #3;9,A%
270  INPUT #4;A%: SET #3;6,CONT$(A%)
280  INPUT #4;A%: SET #3;5,BAUD%(A%)
290  INPUT #4;A$
295  APPEND #3
300 END FOR LP
310 CLOSE #4
320 CLOSE_DATA #3
330 STOP
340 :
500 DEFine FuNction CONV$(S$)
510  IF S$=CHR$(0) THEN RETurn ""
520  S$=S$(3 TO)
530  N$=""
540  FOR N=1 TO LEN(S$)-2 STEP 2
550   I=(CODE(S$(1))-48)*16+CODE(S$(2))-48
560   S$=S$(3 TO)
570   N$=N$&AR$(I)&","
580  END FOR N
590   I=(CODE(S$(1))-48)*16+CODE(S$(2))-48
600   N$=N$&AR$(I)
610   PRINT N$
620   RETurn N$
630 END DEFine
1000 :
1010 DEFine PROCedure ARRAY
1020 REMark MAKE AN ARRAY WITH THE REQUIRED SYMBOL IN EACH POSITION
1030 DIM AR$(255,4)
1040 RESTORE
1050 FOR F=0 TO 31
1060  READ AR$(F)
1070 END FOR F
1080 FOR F=32 TO 126
1090  AR$(F)="'"&CHR$(F)
1100 END FOR F
1110 AR$(127)="DEL"
1120 FOR F=128 TO 191
1130  AR$(F)='"'&CHR$(F)
1140 END FOR F
1150 FOR F=192 TO 255
1160  AR$(F)=F
1170 END FOR F
1180 :
1190 REMark MAKE UP AN ARRAY OF BAUDS
1200 DIM BAUD%(6)
1210 FOR F=0 TO 6: READ BAUD%(F)
1220 :
1230 REMark MAKE UP A PARITY ARRAY
1240 DIM PARITY$(4,5)
1250 FOR F=0 TO 4: READ PARITY$(F)
1260 :
1270 REMark MAKE UP A CONTINUITY ARRAY
1280 DIM CONT$(1,4)
1290 FOR F=0 TO 1: READ CONT$(F)
1300 END DEFine
2000 :
2010 DATA "NUL","SOH","STX","ETX","EOT","ENQ","ACK","BEL"
2020 DATA "BS","HT","LF","VT","FF","CR","SO","SI"
2030 DATA "DLE","DC1","DC2","DC3","DC4","NAK","SYN","ETB"
2040 DATA "CAN","EM","SUB","ESC","FS","GS","RS","US"
2050 :
2060 DATA 75,300,600,1200,2400,4800,9600
2070 :
2080 DATA "NONE","SPACE","MARK","ODD","EVEN"
2090 :
2100 DATA "YES","NO"
